Sieve

Sieve to skryptowy język służący do automatyzacji wielu zadań związanych z kontami pocztowymi (na przykład automatycznemu odpowiadaniu, kopiowaniu wiadomości na inny adres, czy odrzucaniem niektórych wiadomości). Skrypt Sieve działa po stronie serwera.

Zarządzenie skryptem Sieve jest możliwe z:

programu pocztowego (np. w Thunderbird wymagany dodatkowy add-on),
skryptu perl sieve-connect - zainstalowany na serwerach MyDevil,
webmaila Roundcube (Ustawienia → Filtry) - nie jest wymagana znajomość składni.

Struktura skryptu Sieve nie jest skomplikowana i do napisania najprostszej reguły nie potrzeba znać żadnego języka programowania. Skrypt składa się z listy prostych poleceń, takich jak: "fileinto" (przenieś do folderu), "if" (jeśli jakiś warunek jest spełniony), "discard" (odrzuć), etc.

Składnia

require ["fileinto", "reject", "vacation", "regex", "relational", "comparator-i;ascii-numeric"];

if size :over 1024K {
  reject "Wiadomość niedostarczona. Zbyt duży rozmiar.";
  stop;
}

require["..."]; - Ta linia informuje z jakich modułów będziemy korzystać (fileinto do umieszczenia maila w folderze, reject do odrzucania wiadomości, vacation do wysyłania automatycznej wiadomości, regex do wykorzystania wyrażeń regularnych oraz relational wraz z comparator-i;ascii-numeric do porównań numerycznych).

if size :over 1024K { - Ta linia sprawdza czy rozmiar wiadomości jest większy niż 1024KB.

reject "(...)"; - W tej linii wiadomość jest odrzucana.

stop; - W tej linii Steve przestaje analizować dalszą część skryptu. } - Nawias zamykający to, co się dzieje po spełnieniu warunku w if.

Test

size Sprawdza czy rozmiar wiadomości jest większy :over, bądź mniejszy :under od podanej wartości w M(megabajtach), K(kilobajtach) bądź domyślnie w bajtach (na przykład 10M, 20K, 1024).

header Sprawdzanie pól nagłówka.

address Sprawdzanie tylko adresu z nagłówka. Na przykład mail wysłano jako Jan Nowak <jnowak@domena>. Zdanie header "From" :is "jnowak@domena" jest fałszywe, natomiast address :is "jnowak@domena" jest prawdziwe.

allof (lista testów) Zwraca prawdę tylko wtedy, gdy każdy z testów z listy jest prawdziwy.

anyof (lista testów) Zwraca prawdę, gdy dowolny z testów z listy jest prawdziwy.

true Zawsze zwraca prawdę.

false Zawsze zwraca fałsz.

not <test> Zwraca fałsz gdy test zwrócił prawdę i vice-versa.

Porównania

:is Wartość testowanego pola musi być identyczna z podanym parametrem.

:matches Wartość testowanego pola musi pasować do podanego wzorca. We wzorcu poza znakami można używać * - zero lub więcej dowolnych znaków oraz ? - dokładanie jeden dowolny znak.

:contains Wartość testowanego pola musi zawierać podany parametr.

:over Działa tylko dla liczb. Jeżeli podana wartość jest większa niż sprawdzana wartość zwraca prawdę.

:under Działa tylko dla liczb. Jeżeli podana wartość jest mniejsza niż sprawdzana wartość zwraca prawdę.

:count Pozwala przeliczać ile jest pozycji w danym polu.

Konstrukcja

[...] Nawiasy kwadratowe służą do wskazywania grup. Na przykład ["Jan","Adam","Michał"] wskazuje grupę trzech osób.

{...} Nawiasy klamrowe służą do wskazywania bloku instrukcji, które muszą zostać wykonane jeżeli wynik testu będzie prawdą.

if Służy do sprawdzania czy podane wyrażenie jest prawdziwe. Jeżeli jest to wykonywany jest blok instrukcji podany po if.

else W przypadku gdy wyrażenie w if jest fałszywe to wykonywane jest blok instrukcji podany po else.

elseif Połączenie else i if. Gdy wyrażenie w if jest fałszywe to wykonywany jest kolejny if.

stop Kończy działanie skryptu.

Akcje

keep Zatrzymuje wiadomość w obecnym folderze.

fileinto "nazwafolderu" Przenosi wiadomość do wskazanego folderu. Jeżeli ten nie istnieje, to wiadomość trafi do skrzynki odbiorczej. discard Usuwa wiadomość bez powiadamiania o tym nadawcy.

reject "powód" Zwraca wiadomość z błędem do nadawcy z opcjonalnym powodem.

redirect "adres_email" Wysyła dalej wiadomość bez zatrzymania jej kopii o ile keep bądź fileinto nie zostanie wykonane.

Komentarz

# Komentarz jednoliniowy od znaku '#' do końca linii. Treść jest ignorowana przez parser Sieve.
/* Komentarz blokowy
 * Wszystkie linijki są ignorowane od momentu rozpoczęcia komentarza ciągiem znaków '/*',
 * aż do momentu zakończenia komentarza ciągiem znaków */

Przykłady

Na wiadomości kierowane do jan.nowak@domena i j.nowak@domena będzie wysyłana automatyczna odpowiedź:

require ["vacation"];
vacation
  # Wyślij maksymalnie raz dziennie do tego samego adresata
  :days 1
  :subject "Poza biurem - odpowiedź automatyczna"
  :addresses ["jan.nowak@domena", "j.nowak@domena"]
"Dzień dobry,
jestem poza biurem, proszę się kontaktować z Adamem Nowakiem adam.nowak@domena.
Pozdrawiam,
Jan Nowak";

Wiadomości od newsletter@domena będą trzymane w folderze INBOX.Newsletters:

if address :is "From" "newsletter@domena" {
  fileinto "INBOX.Newsletters";
  stop;
}

Wiadomości z domeny domena będą trzymane w folderze INBOX.Example:

if address :is "From" "newsletter@mypals.org" {
  fileinto "INBOX.Example";
  stop;
}

Usuwa maile z podanymi typami załączników:

if header :contains "x-attached"
  [".exe",".bat",".js",".com",".cmd",".ini",".dll",".bas",".cpl",".drv",".inf",".sys",".pif"] {
  discard;
  stop;
}

Odrzuca wiadomości większe niż 5MB powiadamiając o tym nadawcę.

if size :over 5M {
   reject "Wielkość wiadomości maksymalnie 5MB.";
}

Wiadomości od Adam Adamski, które nie zostały nikomu innemu przesłane będą trzymane w folderze INBOX.Adam:

if allof(
  header :contains ["From"] "Adam Adamski",
  header :is ["Bcc:","Cc:"] ""
){
  fileinto "INBOX.Adam";
}

Spam

Opcje konfiguracji dotyczące zachowania wobec maili wykrytych jako spam są dostępne poprzez Devil jak i Devil jak i DevilWEB. Przez Sieve natomiast można dodać m.in. dodatkowe akcje wobec maili wykrytych jako spam, otrzymujących daną wartość punktową.

Do każdej wiadomości email dodawany są nagłówki:

X-Spam-Score informujący o prawdopodobieństwie spamu (0-normalna wiadomość, 5 - prawdopodobny spam, >10 automatyczne odrzucane przez mydevil)
X-Spam-Flag informujący o tym, że wiadomość została zidentyfikowana jako spam.

Poniżej znajduje się kilka rodzajów filtrów antyspamowych.

Usunięcie wiadomości oznaczonej jako spam:

if header :contains "X-Spam-Flag" "YES" {
discard;
}

Przeniesienie wiadomości oznaczonej jako spam do katalogu SPAM:

if header :contains "X-Spam-Flag" "YES" {
fileinto "SPAM";
}

Przeniesienie wiadomości, która ma małe prawdopodobieństwo bycia spamem do katalogu Mozliwy_Spam. Wiadomości z dużym prawdopodobieństwem bycia spamem będą zwracane nadawcy z błędem:

if header :value "le" :comparator "i;ascii-numeric" "x-spam-score" "5" {
fileinto "Mozliwy_spam";
} elsif header :value "gt" :comparator "i;ascii-numeric" "x-spam-score" "5"  {
reject "Wiadomość oznaczona jako spam";
}

Zobacz też

SpamAssassin